[Oracleasm-commits] jlbec commits r393 - trunk

[svn-commits at oss.oracle.com]

Author: jlbec
Date: 2008-12-03 16:03:18 -0800 (Wed, 03 Dec 2008)
New Revision: 393

Added:
   trunk/kver.m4
Modified:
   trunk/aclocal.m4
   trunk/configure.in
Log:

configure.in: Use a standard KVER function.

ocfs2 has a nice KVER function that does everything we're doing.  Let's
use it rather than coding it ourselves.



Modified: trunk/aclocal.m4
===================================================================
--- trunk/aclocal.m4	2008-12-04 00:02:23 UTC (rev 392)
+++ trunk/aclocal.m4	2008-12-04 00:03:18 UTC (rev 393)
@@ -1,2 +1,3 @@
+m4_include([mbvendor.m4])
+m4_include([kver.m4])
 m4_include([kfeature.m4])
-m4_include([mbvendor.m4])

Modified: trunk/configure.in
===================================================================
--- trunk/configure.in	2008-12-04 00:02:23 UTC (rev 392)
+++ trunk/configure.in	2008-12-04 00:03:18 UTC (rev 393)
@@ -75,54 +75,13 @@
   AC_SUBST(KERNELDIR)
 fi
 
-if test -f "${KERNELDIR}/include/linux/utsrelease.h"; then
-  UTS_HEADER=utsrelease.h
-else
-  UTS_HEADER=version.h
-fi
+KBUILDINC="$KERNELDIR/include"
+kversion=none
+OCFS2_CHECK_KVER($KBUILDINC, kversion, , , :)
 
-AC_MSG_CHECKING(for kernel version)
-if test -n "$KERNELDIR"; then
-  kernelinc="${KERNELDIR}/include"
-
-  saved_CPPFLAGS="$CPPFLAGS"
-  CPPFLAGS="-I${kernelinc} $CPPFLAGS"
-  saved_CFLAGS="$CFLAGS"
-  CFLAGS="$CFLAGS $M64"
-
-
-  rm -f conf.kvertest
-  AC_TRY_RUN([
-#include <stdio.h>
-#include <linux/${UTS_HEADER}>
-
-int
-main (void)
-{
-#ifdef UTS_RELEASE
-  FILE *f;
-  f = fopen ("conf.kvertest", "w");
-  if (!f)
-    return 1;
-  fprintf (f, "%s", UTS_RELEASE);
-  fclose (f);
-  return 0;
-#else
-  return 1;
-#endif
-}],kversion=`cat conf.kvertest`, kversion="none")
-  rm -f conf.kvertest
-
-  CPPFLAGS="$saved_CPPFLAGS"
-  CFLAGS="$saved_CFLAGS"
-else
-  kversion="none"
-fi
-
 BUILD_DRIVER=
 case "$kversion" in
   2.6.*)
-    AC_MSG_RESULT($kversion)
     BUILD_DRIVER=yes
     ;;
   none)

Added: trunk/kver.m4
===================================================================
--- trunk/kver.m4	                        (rev 0)
+++ trunk/kver.m4	2008-12-04 00:03:18 UTC (rev 393)
@@ -0,0 +1,53 @@
+dnl OCFS2_CHECK_KVER(INCLUDE-PATH, VERSION-VARIABLE, [DESCRIPTION],
+dnl                             [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+AC_DEFUN([OCFS2_CHECK_KVER],
+  [AC_LANG_PREPROC_REQUIRE()dnl
+   AC_REQUIRE([AC_PROG_EGREP])dnl
+
+   check_kver_DESC="$3"
+
+   if test -n "$check_kver_DESC"; then
+     check_kver_DESC=" $check_kver_DESC"
+   fi
+
+   if test -f "$1/linux/utsrelease.h"; then
+     UTS_HEADER=utsrelease.h
+   else
+     UTS_HEADER=version.h
+   fi
+
+   check_kver_saved_CPPFLAGS="$CPPFLAGS"
+   CPPFLAGS="-I$1 $CPPFLAGS -nostdinc"
+
+   AC_MSG_CHECKING(for kernel$check_kver_DESC version)
+
+   AC_LANG_CONFTEST([AC_LANG_SOURCE([
+#include <linux/${UTS_HEADER}>
+
+#ifdef UTS_RELEASE
+check_kver_RESULT=UTS_RELEASE
+#else
+check_kver_RESULT=none
+#endif
+])])
+
+   if (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
+     $EGREP "^check_kver_RESULT=" > conftest.kver 2>&1; then
+     . ./conftest.kver
+   else
+     check_kver_RESULT='none'
+   fi
+
+   AC_MSG_RESULT($check_kver_RESULT)
+   rm -f conftest*
+
+   CPPFLAGS="$check_kver_saved_CPPFLAGS"
+
+   if test "x$check_kver_RESULT" != "xnone"; then
+     $2=$check_kver_RESULT
+     m4_default([$4], :)
+   else
+     m4_default([$5],
+       [AC_MSG_ERROR([Could not determine kernel$check_kver_DESC version.])])
+   fi
+])# OCFS2_CHECK_KVER